mirror of
https://github.com/hathach/tinyusb.git
synced 2026-08-18 11:02:16 +00:00
1d915b6b59
bsp, hil: flash with the unified OpenOCD fork https://github.com/hathach/openocd (branch tinyusb) is mainline plus every config these boards need: RPi RP2350, ADI max32/max78, the MounRiver WCH configs, and the wlinke adapter on mainline's riscv target. It is a superset of the vendor forks, so one 'openocd' covers all boards; -DOPENOCD=/OPENOCD= still select another, msdk's when MAXIM_PATH is set. Drops family_flash_openocd_wch and the OPENOCD_WCH pair, dedups family_flash_openocd_adi, aligns ch583's work area, and points hil at the flasher's own config instead of generating one per probe. Verified: HIL green on all four WCH boards and max32666fthr.
121 lines
3.7 KiB
CMake
121 lines
3.7 KiB
CMake
include_guard()
|
|
|
|
set(CH32_FAMILY ch32v30x)
|
|
set(SDK_DIR ${TOP}/hw/mcu/wch/ch32v307)
|
|
set(SDK_SRC_DIR ${SDK_DIR}/EVT/EXAM/SRC)
|
|
|
|
# include board specific
|
|
include(${CMAKE_CURRENT_LIST_DIR}/boards/${BOARD}/board.cmake)
|
|
|
|
# toolchain set up
|
|
set(CMAKE_SYSTEM_CPU rv32imac-ilp32 CACHE INTERNAL "System Processor")
|
|
set(CMAKE_TOOLCHAIN_FILE ${TOP}/examples/build_system/cmake/toolchain/riscv_${TOOLCHAIN}.cmake)
|
|
|
|
set(FAMILY_MCUS CH32V307 CACHE INTERNAL "")
|
|
set(OPENOCD_OPTION "-f ${CMAKE_CURRENT_LIST_DIR}/wch-riscv.cfg")
|
|
|
|
# default to highspeed, used to select USBFS / USBHS driver
|
|
if (NOT DEFINED SPEED)
|
|
set(SPEED high)
|
|
endif()
|
|
|
|
#------------------------------------
|
|
# Startup & Linker script
|
|
#------------------------------------
|
|
if (NOT DEFINED LD_FILE_GNU)
|
|
set(LD_FILE_GNU ${CMAKE_CURRENT_LIST_DIR}/linker/ch32v30x.ld)
|
|
endif ()
|
|
set(LD_FILE_Clang ${LD_FILE_GNU})
|
|
if (NOT DEFINED STARTUP_FILE_GNU)
|
|
set(STARTUP_FILE_GNU ${SDK_SRC_DIR}/Startup/startup_${CH32_FAMILY}_D8C.S)
|
|
endif ()
|
|
set(STARTUP_FILE_Clang ${STARTUP_FILE_GNU})
|
|
|
|
#------------------------------------
|
|
# Board Target
|
|
#------------------------------------
|
|
function(family_add_board BOARD_TARGET)
|
|
add_library(${BOARD_TARGET} STATIC
|
|
${SDK_SRC_DIR}/Core/core_riscv.c
|
|
${SDK_SRC_DIR}/Peripheral/src/${CH32_FAMILY}_gpio.c
|
|
${SDK_SRC_DIR}/Peripheral/src/${CH32_FAMILY}_misc.c
|
|
${SDK_SRC_DIR}/Peripheral/src/${CH32_FAMILY}_rcc.c
|
|
${SDK_SRC_DIR}/Peripheral/src/${CH32_FAMILY}_usart.c
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/${CH32_FAMILY}_it.c
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/system_${CH32_FAMILY}.c
|
|
)
|
|
target_include_directories(${BOARD_TARGET} PUBLIC
|
|
${SDK_SRC_DIR}/Core
|
|
${SDK_SRC_DIR}/Peripheral/inc
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}
|
|
)
|
|
if (SPEED STREQUAL high)
|
|
target_compile_definitions(${BOARD_TARGET} PUBLIC
|
|
CFG_TUD_WCH_USBIP_USBHS=1
|
|
# BOARD_TUD_MAX_SPEED=OPT_MODE_HIGH_SPEED
|
|
)
|
|
else ()
|
|
target_compile_definitions(${BOARD_TARGET} PUBLIC
|
|
CFG_TUD_WCH_USBIP_USBFS=1
|
|
)
|
|
endif ()
|
|
|
|
update_board(${BOARD_TARGET})
|
|
|
|
if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
|
|
target_compile_options(${BOARD_TARGET} PUBLIC
|
|
-msmall-data-limit=8
|
|
-mno-save-restore
|
|
-fmessage-length=0
|
|
-fsigned-char
|
|
)
|
|
endif ()
|
|
endfunction()
|
|
|
|
#------------------------------------
|
|
# Functions
|
|
#------------------------------------
|
|
function(family_configure_example TARGET RTOS)
|
|
family_configure_common(${TARGET} ${RTOS})
|
|
family_add_tinyusb(${TARGET} OPT_MCU_CH32V307)
|
|
|
|
target_sources(${TARGET} PUBLIC
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/family.c
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/debug_uart.c
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/../board.c
|
|
${TOP}/src/portable/wch/dcd_ch32_usbhs.c
|
|
${TOP}/src/portable/wch/dcd_ch32_usbfs.c
|
|
${STARTUP_FILE_${CMAKE_C_COMPILER_ID}}
|
|
)
|
|
target_include_directories(${TARGET} PUBLIC
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/../../
|
|
${CMAKE_CURRENT_FUNCTION_LIST_DIR}/boards/${BOARD}
|
|
)
|
|
|
|
if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
|
|
target_link_options(${TARGET} PUBLIC
|
|
-nostartfiles
|
|
--specs=nosys.specs --specs=nano.specs
|
|
-Wl,--defsym=__FLASH_SIZE=${LD_FLASH_SIZE}
|
|
-Wl,--defsym=__RAM_SIZE=${LD_RAM_SIZE}
|
|
"LINKER:--script=${LD_FILE_GNU}"
|
|
)
|
|
elseif (CMAKE_C_COMPILER_ID STREQUAL "Clang")
|
|
message(FATAL_ERROR "Clang is not supported")
|
|
elseif (CMAKE_C_COMPILER_ID STREQUAL "IAR")
|
|
target_link_options(${TARGET} PUBLIC
|
|
"LINKER:--config=${LD_FILE_IAR}"
|
|
)
|
|
endif ()
|
|
|
|
set_source_files_properties(${STARTUP_FILE_${CMAKE_C_COMPILER_ID}} PROPERTIES
|
|
SKIP_LINTING ON
|
|
COMPILE_OPTIONS -w)
|
|
|
|
# Flashing
|
|
family_add_bin_hex(${TARGET})
|
|
family_flash_openocd(${TARGET})
|
|
family_flash_wlink_rs(${TARGET})
|
|
endfunction()
|